use lib "../lib";
use Getopt::Long;
use WebGUI::Session;
use WebGUI::Macro;

my ($session, $macro, $params) = start();
runMacro($session, $macro, $params);
finish($session);

#-------------------------------------------------
sub runMacro {
    my ($session, $macro, $params) = @_;
    my $cmd = "use WebGUI::Macro::".$macro;
    eval($cmd);
    if ($@) {
        print "Error: $@\n";
        exit;
    }
    $macro = "WebGUI::Macro::".$macro."::process";
    print &$macro($session, @{$params})."\n";
}



#-------------------------------------------------
sub start {
    my $configFile;
    my @params = ();
    my $macro = "";
    my $userId = 1;
    my $help;
    $| = 1; #disable output buffering
    GetOptions(
        'configFile=s'      => \$configFile,
        'macro=s'           => \$macro,
        'params=s{0,10}'    => \@params,
        'userId=s'         => \$userId,
        'help'              => \$help,
    );
    if ($help || $configFile eq "" || $macro eq "") {
        print <<STOP;
        Usage perl $0 --configFile=www.example.com.conf --macro=At_username

        Options:

        --configFile    The WebGUI config file to execute this macro under.

        -help           Print this message.

        --macro         The filename of the macro to execute (without the .pm).

        --params        A parameter string to pass in to the macro. You can specify 
                        this multiple times to add multiple parameters.

        --userId        The userId you want to run this under. Defaults to "1" aka 
                        "Visitor".
STOP
        exit;
    } 
    my $session = WebGUI::Session->open("..",$configFile);
    $session->user({userId=>$userId});
    return ($session, $macro, \@params);
}

#-------------------------------------------------
sub finish {
    my $session = shift;
    $session->var->end;
    $session->close;
}